Inglehart Scale

Inglehart Scale	Examples
Resources DataFile DataDocumentation InfoExamples ?	Back

Building the Post-materialism scale (continued)

This documents adds some new twists to the creation of the postmaterialism scale. The goal being to add some refinements to your skills with transformations.

In our first attempt to create the postmaterialism scale, we have written a logical condition for each of the cells this table:

	First priority q11a
"2nd Priority q11b	(1) Maintain order	(2) More to say	(3) Fight raising prices	(4) Freedom of speech
(1) Maintain order	-	3	1	3
(2) More to say	2	-	2	4
(3) Prices	1	3	-	3
(4)Freedom speech	2	4	2	-

As for each score (code) of the Postmaterialism variable, you have more than one cell (condition) in the table, you can also write an SPSS command for each of the four scores, using more complex logical expressions : (There are some further refinements in the sequence as well in the sequence below.

COMPUTE pm1=0.
IF (q11a=3 AND q11b=1) OR (q11a=1 AND q11b=3) pm1=1.
IF (q11a=2 AND q11b=4) OR (q11a=4 AND q11b=2) pm1=4.
IF (q11a=1 AND q11b=2) OR (q11a=3 AND q11b=2)
    OR 
   (q11a=1 AND q11b=4) OR (q11a=3 AND q11b=4) PM1=2.
IF (q11a=2 AND q11b=1) OR (q11a=4 AND q11b=1)
   OR 
   (q11a=2 AND q11b=3) OR (q11a=4 AND q11b=3) pm1=3.
   
IF MISSING (q11a) or MISSING (q11b) pm1=9.
MISSING VALUES PM1(9).

VARIABLE LABEL PM1 "Inglehart Postmaterialism Scale".
VALUE LABELS  PM1 1 "Materialist" 
                  2 "Rather materialist" 
                  3 "Rather postmaterialist" 
				  4 "Postmaterialist" 
				  9 "?".
FORMATS PM1(F1).
VARIABLE LEVEL PM1(Ordinal).

FREQUENCIES VAR=PM1.

This command sequence builds the PM1 Scale; a Frequency at the end shows the resulting variable.

Comments on the commands:

COMPUTE PM1=0.
creates a variable PM1 and sets all its values to 0. (Good practice to see that everything went smoothly; if you find a 0 code in the frequency table, it will mean that there is a problem somewhere.
IF...
Four conditional transformations for the four conditions (scores) as defined in the above logical table.
IF MISSING (q11a) or MISSING (q11b) PM1=9.
If a value is missing on one of the variables the result will be PM1=9. (MISSING() is a logical function: its value is true, when the observation is missing, false otherwise.
MISSING VALUES PM1(9).
Declares 9 as a (user) missing value, as the preceding command line assigned a code of 9 to all missing answers on one or both variables. If you forget this declaration, 9 will be considered a normal, valid value, i.e. another level of postmaterialism. [MISSING VALUES command]
VARIABLE LABEL Defines a value label for the newly created variable. Although defining labels is optional, it is highly recommended. [VARIABLE LABELS command]
VALUE LABELS Defines value labels for all codes of the PM1 variable. Although defining labels is optional, it is highly recommended to produce readable tables. [VALUE LABELS command]
FORMATS PM1(F1). Defines the display format; this simply means that you want to have a single position displayed and no decimal positions. By default SPSS displays 2 decimals, i.e. instead of showing a code of "1" it would show "1.00" (cosmetic option). [FORMATS command]
VARIABLE LEVEL PM1(ordinal). Defines measurement level as ordinal. Again this is optional, but recommended as some commands in SPSS require this. [VAR LEVEL command]

The FREQUENCY command is of course not part of the command sequence needed to build the scale, but it is highly recommended. For two reasons:

Check if the PM1 variable created is as it should be or if there was a problem (showing codes other than 1,2,3,4 and 9 as missing).
Produce a visible result. If you do not specify a statistical procedure after a transformation sequence, nothing will be produced and shown in the output... except if you made a syntax error; then you will find an error message there....

Back